VBA基础

Sub 内置函数调用()
    Dim i As Integer
    i = 2

    With ThisWorkbook.Sheets("内置函数")
        For i = 2 To 7
            .Cells(i, 12) = Application.WorksheetFunction.SumIfs(.Columns(5), .Columns(3), .Cells(i, 9), .Columns(4), .Cells(i, 10)) '直接调用
        Next i
    End With
End Sub

Sub 静态数组()

    '静态数组：在声明时就指定空间大小(元素个数)的数组，就是静态数组，大小不可变化，否则会溢出

    Dim Arr1(0 To 6) As Integer  '7个元素（0-6）
    Dim Arr2(1 To 7) As Integer  '同样是7个元素（1-7）

    Debug.Print UBound(Arr1) 'UBound函数是Visual Basic和VBA中用于确定数组维度边界的核心函数,它返回数组的上标即6
    Debug.Print UBound(Arr2) '返回7

    Dim i As Integer
    For i = 1 To 7   '给数组赋值
        Arr1(i - 1) = i    'Arr1下标是从0开始的
        Arr2(i) = i * i    'Arr2下标是从1开始的
    Next i

    Arr2(8) = 8 '超出下标的赋值，会出现“越界”的错误

    Dim j As Variant   '数组中的元素可以用for each遍历
    For Each j In Arr1
        Debug.Print j  '在立即窗口打印每个元素
    Next
    For i = 1 To UBound(Arr2)  '也可以用索引引用
        Debug.Print Arr2(i)    '在立即窗口打印每个元素
    Next i

    '以上是一维数组，也可以多维的
    Dim Matrix1(1 To 7, 1 To 7) As String '一个7 * 7的二维数组，
    Dim a As Integer, b As Integer
    For a = 1 To 7                          '双层循环给数组赋值，相当于用行\列的二维坐标索引给二维数组赋值
        For b = 1 To 7
            Matrix1(a, b) = a & "R" & b & "C"
        Next b
    Next a
    '这里在工作表中，从A1单元格开始，.Resize扩展一个和数组大小一致的区域
    ThisWorkbook.Sheets("数组").Range("A1").Resize(7, 7) = Matrix1  '将这个二维数组，写入到工作表

    '当然已可以把工作表中的数据（多行、列）赋值给一个(变体)数组,让它像数组一样遍历获取元素
    Dim Matrix2  '不在指定类型
    Matrix2 = ThisWorkbook.Sheets("数组").Range("A1").Resize(7, 5) '把工作表的7 * 5，即7行\5列的区域赋值给Matrix2

    For a = 1 To UBound(Matrix2, 1)     '双层循环，依次用数组的行/列坐标索引，打印元素
        For b = 1 To UBound(Matrix2, 2)
            Debug.Print Matrix2(a, b)  '在立即窗口打印出数组的元素，即是单元格A1:E7的内容，先行后列
        Next b
    Next a

    For Each j In Matrix2  '当然也可以用for each 遍历，注意二维数组的遍历，是从外层即行开始的
        Debug.Print j
    Next j

    '可以修改数组的值
    Debug.Print Arr1(5)
    Arr1(5) = 100     '修改第五个元素的值
    Debug.Print Arr1(5)

    Debug.Print Matrix1(3, 4)
    Matrix1(3, 4) = "你好"  '修改二维数组中元素的值
    Debug.Print Matrix1(3, 4)

End Sub
Sub 动态数组()
    '动态数组：用数组存储内容，但不确定数组的大小需求，而需要在程序运行过程中不断扩展的，就需要动态数组

    Dim DyArr() As Variant  '定义一个动态数组，未指定空间
    ReDim DyArr(1 To 4) '初始分配一个空间，只是初始化

    Dim i As Integer
    For i = 1 To 3  '动态数组的三个元素赋值
        DyArr(i) = i
    Next

    Dim j
    For Each j In DyArr
        Debug.Print j '在立即窗口打印数组元素，循环5次(分配的空间是5个),只打印出赋值的3个元素值
    Next j

    ReDim Preserve DyArr(1 To 5) ' 如果要扩展数据大小，用来继续存储不确定的数据，必须要用 ReDim Preserve，这样会保留数据并、扩展大小
    DyArr(4) = 4
    DyArr(5) = 5
    For Each j In DyArr
        Debug.Print j 'Redim Preserve保留原数据，打印1、2、3、4、5
    Next j

    ReDim DyArr(1 To 5) 'ReDim，相当于重新定义空间，原来1-3的元素会被清空，不会保留
    DyArr(4) = 4
    DyArr(5) = 5

    For Each j In DyArr
        Debug.Print j 'Redim清空原数据，打印三个空值和4、5
    Next j

End Sub

Sub 字典()
    '如果先引用了 Microsoft Scripting Runtime库，直接声明一个字典变量即可
    Dim dict As New Scripting.Dictionary

    '添加元素
    dict.Add "东风日产", 536 '字典的.add方法，添加键和值
    dict.Add "别克", 937
    dict("奥迪") = 300 '简写方式，直接给键付一个值也是可以的

    '检查键是否存在，.Exists("键")的方法
    If dict.Exists("东风日产") Then
        Debug.Print dict("东风日产")
    End If

    If dict.Exists("雪佛兰") Then
        Debug.Print dict("雪佛兰") '不存在则什么都不会在立即窗口打印
    End If

    'dict.Add "东风日产", 396 '尝试给字典增加一个已存在的键，看会发生什么？错误457，该关键字*****

    Debug.Print dict("东风日产")
    dict("东风日产") = 396 '如果要修改一个键对应的值，重新赋值就可以了
    Debug.Print dict("东风日产")

    '关于字典的遍历，For_each每个元素 和 用字索引都可以
    Dim key As Variant
    For Each key In dict.Keys  '循环每个键
        Debug.Print key & ":" & dict(key) '获取每个键和对应的值
    Next key
    Dim value As Variant
    For Each value In dict.Items '循环每个值
        Debug.Print value
    Next value

    '用字典的索引
    Dim i As Long
    For i = 0 To dict.Count - 1  '注意字典的索引是从0开始的，.count方法用于元素的计数，有3个元素，循环从0开始，则是0、1、2，上标要减去1
        Debug.Print dict.Keys(i) & ":" & dict.Items(i)
    Next i

    Debug.Print dict.Count '获取字典元素的数量
    dict.Remove "奥迪"    ' 删除项
    Debug.Print dict.Count '数量变成2

    dict.RemoveAll         ' 清空字典，在代码优化中提到的“内存管理和对象释放”，数组是使用后及时释放掉，不占用内存，也可以提高效率！
    Debug.Print dict.Count '数量变成0

    ' 没有事先引用 Microsoft Scripting Runtime库，后期绑定是一样的，可以尝试下
    Dim dict_x As Object
    Set dict_x = CreateObject("Scripting.Dictionary")

End Sub

Sub 集合()
    Dim Col As New Collection '创建一个集合

    '集合添加元素的方式和字典类似，用.add方法
    Col.Add 536              '集合的元素可以不带键
    Col.Add 937, key:="别克" '集合的元素可以带键，第二个元素是键，显示的用key:=赋值
    Col.Add 300, "奥迪"      '不显示的键，放在第二个参数位置即可


    '获取元素，同样可以通过for_each 和 索引
    Dim itm As Variant
    For Each itm In Col
        Debug.Print itm  '获取每个元素值，集合是不要求必要有键的，元素只返回值
    Next itm

    Dim i As Long
    For i = 1 To Col.Count  '注意集合的索引是从1开始的，集合同样有.count方法，返回元素的个数
        Debug.Print Col.item(i)
    Next i

    'Col.Add 400, "奥迪"      '元素可以没有key（键），但是key元素必须是唯一的，错误****

    '和字典的通过重新赋值改变键对应的值不同，字典里修改元素，必须先移除，在添加
    Col.Remove "奥迪"  '移除元素
    Col.Add 400, "奥迪"
    Debug.Print Col.item("奥迪")

    '也可以通过索引移除
    Col.Remove 3  '奥迪是我们插入的第三个元素，通过索引移除
    Col.Add 500, "奥迪"
    Debug.Print Col.item("奥迪")
    Debug.Print Col.item(3)

    '集合支持有序存储，.add添加的顺序可支持位置
    Col.Remove 3  '移除第三个元素，“奥迪”
    Col.Add 500, "奥迪", 2  '在第二个位置前插入，“奥迪”即在第二个位置，
    'Col.Add 500, key:="奥迪", before:=2 '显示指定
    Debug.Print Col.item("奥迪")
    Debug.Print Col.item(2)

End Sub