VBA基础

Application  '顶级对象，应用程序本身
│
├─ Workbooks (所有打开的工作簿集合)'Workbook父对象
│   │
│   └─ Workbook (单个工作簿)'Worksheets父对象
│       │
│       ├─ Worksheets (所有工作表集合) 'Worksheet父对象
│       │   │
│       │   └─ Worksheet (单个工作表) 'Range的父对象
│       │       │
│       │       ├─ Range (单元格及区域)'Worksheet子对象
│       │       │
│       │       ├─ ChartObjects (嵌入的图表集合)
│       │       │   └─ ChartObject → Chart (嵌入的图表)
│       │       │
│       │       └─ Shapes (形状/图形集合，如文本框、图片等)
│       │           └─ Shape (单个形状)
│       │
│       └─ Charts (独立的图表工作表集合)
│           └─ Chart (独立的图表工作表)
│
└─ Windows (所有窗口集合)

Sub 不关闭屏幕刷新()
    Dim i As Integer

    Dim startTime As Double
    Dim endTime As Double

    '不关闭屏幕刷新执行代码
    startTime = Timer   '记录开始时间
    For i = 1 To 10     '执行10次打开和关闭同一个工薄的操作
        Workbooks.Open ("C:\Users\MagicBook\Desktop\kk\工作薄对象\工作簿4.xlsx")
        ActiveWorkbook.Close
    Next i
    endTime = Timer     '记录结束时间

    MsgBox "执行时间: " & endTime - startTime & " 秒"  '观察执行耗费时长

End Sub
Sub 关闭屏幕刷新()
    Dim i As Integer

    Dim startTime As Double
    Dim endTime As Double

     '关闭屏幕刷新执行代码
    Application.ScreenUpdating = False
    startTime = Timer   '记录开始时间
    For i = 1 To 10     '执行10次打开和关闭同一个工薄的操作
        Workbooks.Open ("C:\Users\MagicBook\Desktop\kk\工作薄对象\工作簿4.xlsx")
        ActiveWorkbook.Close
    Next i
    endTime = Timer     '记录结束时间
    Application.ScreenUpdating = True

    MsgBox "执行时间: " & endTime - startTime & " 秒"  '观察执行耗费时长

End Sub
Sub 不关闭警告()
    '模拟一个打开工作簿、新建工作表、写入内容后在删除工作表的过程，没有关闭警告时，会弹出内容让你选择
    Workbooks.Open ("C:\Users\MagicBook\Desktop\kk\工作薄对象\工作簿4.xlsx")

    ActiveWorkbook.Sheets.Add After:=ActiveWorkbook.Sheets(ActiveWorkbook.Sheets.Count)    '在新建工作薄增加一个工作表，位置在最后
    ActiveSheet.Range("A1") = "表1"
    ActiveWorkbook.Save
    ActiveSheet.Delete
    ActiveWorkbook.Close

End Sub
Sub 关闭警告()
    '模拟一个打开工作簿、新建工作表、写入内容后在删除工作表的过程,关闭警告后，好像一切都没有发生
    Workbooks.Open ("C:\Users\MagicBook\Desktop\kk\工作薄对象\工作簿4.xlsx")

    Application.DisplayAlerts = False
    ActiveWorkbook.Sheets.Add After:=ActiveWorkbook.Sheets(ActiveWorkbook.Sheets.Count)    '在新建工作薄增加一个工作表，位置在最后
    ActiveSheet.Range("A1") = "表1"
    ActiveWorkbook.Save
    ActiveSheet.Delete
    ActiveWorkbook.Close
    Application.DisplayAlerts = True

End Sub
Sub 在状态栏显示执行过程()
    Dim i As Integer

    Dim startTime As Double
    Dim endTime As Double

     '关闭屏幕刷新执行代码
    Application.ScreenUpdating = False
    startTime = Timer
    For i = 1 To 10
        Application.StatusBar = "第" & i & "次打开"   '状态栏显示执行进度
        Workbooks.Open ("C:\Users\MagicBook\Desktop\kk\工作薄对象\工作簿4.xlsx")
        ActiveWorkbook.Close
    Next i
    endTime = Timer

    Application.ScreenUpdating = True
    Application.StatusBar = False  '关闭状态栏显示

    MsgBox "执行时间: " & endTime - startTime & " 秒"  '观察执行耗费时长

End Sub

Sub 交互1_打开对话框并选择文件()
    Dim FileToOpen As Variant  '声明一个可以存储任何数据类型的Variant变量
    Dim i As Long

    '显示标准的“打开”对话框，并获取选择的文件名，包含完整的路径
    FileToOpen = Application.GetOpenFilename("Excel文件,*.xl*", , "请选择要合并的多个工作簿/表", , True)

    For i = 1 To UBound(FileToOpen)
        Debug.Print FileToOpen(i)
    Next i

End Sub
Sub 交互2_打开指定类型的对话框()
    Dim FileD As Variant  '声明一个FileDialog类型的变量
    Dim i As Long

    '显示标准的“打开”对话框,对话框类型是“选择文件”
    Set FileD = Application.FileDialog(msoFileDialogFilePicker)

    FileD.Title = "选择Excel文件"
    FileD.Filters.Add "Excel文件", "*.xl*"  '过滤器，过滤其他文件，只显示后缀包含.xl的文件
    FileD.AllowMultiSelect = True ' 允许多选
    FileD.Show  '显示对话框

    For i = 1 To FileD.SelectedItems.Count
        Debug.Print FileD.SelectedItems(i)
    Next i

End Sub
Sub 交互3_调用Excel内置对话框()

    Application.Dialogs(xlDialogSaveAs).Show '另存为
    Application.Dialogs(xlDialogOpen).Show '打开文件

End Sub
Sub 交互4_支持数据验证的输入框()
    Dim userInput As Variant

    userInput = Application.InputBox("请输入一个数字", Type:=1) 'Type:=1 表示数值
    MsgBox userInput
    userInput = Application.InputBox(Prompt:="输入内容", Title:="标题", Type:=2) 'Type:=2 表示文本字符串
    MsgBox userInput
    userInput = Application.InputBox(Prompt:="单元格", Title:="单元格引用", Type:=8) 'Type:=8 表示单元格引用
    MsgBox userInput

End Sub
Sub 交互5_指定时间触发程序()

    '5秒钟后在状态栏显示执行过程
    Application.OnTime Now + TimeValue("00:00:05"), "在状态栏显示"

End Sub
Sub 在状态栏显示()
    Dim i As Integer
    For i = 1 To 10
        Application.Wait Now + TimeValue("00:00:01") '停顿 1秒
        Application.StatusBar = "第" & i & "次打开"   '状态栏显示执行进度
    Next i
    Application.StatusBar = False  '关闭状态栏显示

End Sub

Sub 执行工作表内置函数()

    Dim count_品牌_1 As Integer
    Dim count_品牌_2 As Integer

    Dim i As Integer
    Dim Title_1 As Long
    Dim Title_2 As Long

    With ThisWorkbook.Sheets("数据")
        count_品牌_1 = .Range("A1").End(xlDown).Row  '引用单元格引用的方法
        Debug.Print count_品牌_1 - 1
        count_品牌_2 = Application.WorksheetFunction.CountA(.Columns(1)) '用内置函数的方法
        Debug.Print count_品牌_2 - 1

        For i = 2 To count_品牌_2               '用循环的控制语句方法
            Title_1 = Title_1 + .Cells(i, 2)
        Next i
        Debug.Print "台次合计" & Title_1

        Title_2 = Application.WorksheetFunction.Sum(.Columns(2)) '用内置函数的方法
        Debug.Print "台次合计" & Title_2

    End With
End Sub

'新建一个类模块，重命名-类名是clsapp，编写要响应的事件代码，代码如下
'关键字WithEvents声明“APP”作为一个Application应用程序对象的变量
Public WithEvents App As Application

'事件代码有三个，当工作簿被创建时、被打开时、被关闭时，提示不同的内容
' 当新工作簿被创建时触发
Private Sub App_NewWorkbook(ByVal Wb As Workbook)
    MsgBox "新工作簿已创建：" & Wb.Name, vbInformation
End Sub

' 当任意工作簿被打开时触发
Private Sub App_WorkbookOpen(ByVal Wb As Workbook)
    MsgBox "工作簿已打开：" & Wb.Name, vbInformation
End Sub

' 在Excel关闭前触发（可取消关闭）
Private Sub App_WorkbookBeforeClose(ByVal Wb As Workbook, Cancel As Boolean)
    If MsgBox("确认关闭 " & Wb.Name & " 吗？", vbYesNo + vbQuestion) = vbNo Then
        Cancel = True  ' 取消关闭
    End If
End Sub

’新建一个模块，完成初始化类，完成绑定
Dim myApp As clsapp  '声明myaApp是clsapp变量类型

'初始化类实例，绑定Application对象,运行后完成绑定
Sub startAppEvents()
    Set myApp = New clsapp        'myApp变量，被赋值为一个新的clsapp类型
    Set myApp.App = Application   '结合类模块中的Public WithEvents App As Application， 此时myAPP绑定了Applicaiton对象，对Excel的任何的操作都会先判断是否触发了clsapp的事件代码

End Sub
Sub open_workbook()
    Workbooks.Open ("C:\Users\MagicBook\Desktop\新建 Microsoft Excel 工作表.xlsx")
End Sub

'解除绑定，运行后对Excel的操作，不在触发clsapp事件代码
Sub stopAppEvents()
    Set myApp = Nothing  ' 解除绑定
End Sub