拆分字符串中的字符字母和数字

Sub 分离字符串字母和数字()
    Dim Choose_rng, rng As Range
    Dim i As Integer
    Dim str, hz, zm, sz As String
    
    On Error Resume Next
    Set Choose_rng = Application.InputBox("选择需要分离的单元格区域", Type:=8)
    If Err.Number > 0 Then MsgBox "未选择内容": Exit Sub
    If WorksheetFunction.CountA(Choose_rng) = 0 Then MsgBox "选择单元格区域为空": Exit Sub
    On Error GoTo 0
    
    For Each rng In Choose_rng '遍历参数代表区域中的每一个单元格
        If Len(rng) > 0 Then '如果是非空单元格
            For i = 1 To Len(rng.Text) '遍历单元格字符中的每一个字符
                str = Mid(rng.Text, i, 1) '逐个提示字符
                If Asc(str) < 0 Then hz = hz & str '如果ASCII码小于0，串联起来赋值给hz变量
                If str Like "[a-z,A-Z,+,-,*,/]" Then zm = zm & str
                If str Like "#" Or str = "." Then sz = sz & str
            Next i
        End If
        rng.Offset(0, 1) = hz '在选区后面的三个单元格分别写入汉字、数字、和字母
        rng.Offset(0, 2) = zm
        '数字部分需要处理前置、后置小数点及多个小数点同时出现的问题，方法为将小数点转换成空格，在用trim去除多余的空格，最后将空格替换成小数点
        rng.Offset(0, 3) = Replace(WorksheetFunction.Trim(Replace(sz, ".", " ")), " ", ".")
        hz = "": zm = "": sz = ""
    Next rng
    Choose_rng.Offset(-1, 1).Resize(1, 3) = Array("汉字", "字母", "数值") '写入标题
    
    MsgBox "分离完成"
End Sub

1：对某列单元格区域内的字符拆分出字符、字母、和数字

2：自主修改部分代码做成小的应用

3：多适用字符串、字母、数字的混合记录的分离

源码视频演示

批量拆分单元格区域中的字符字母和数字

目录